#!/usr/bin/perl -w
#
# postfix-pdel - deletes message containing specified address from
# Postfix queue. Matches either sender or recipient address.
#
# Usage: postfix-pdel <pattern>
#

use strict;
use File::Basename;

my $scriptname = basename($0);

my $func = "";
if ( $scriptname eq "postfix-pdel" ) {
    $func = "-d";
} elsif ( $scriptname eq "postfix-phold" ) {
    $func = "-h";
} elsif ( $scriptname eq "postfix-punhold" ) {
    $func = "-H";
}

# Change these paths if necessary.
my $LISTQ = "/usr/sbin/postqueue -p";
my $POSTSUPER = "/usr/sbin/postsuper";

my $email_addr = "";
my $qid = "";
my $euid = $>;

if ( @ARGV !=  1 ) {
    die "Usage: $0 <pattern>\n";
} else {
    $email_addr = $ARGV[0];
}

if ( $euid != 0 ) {
        die "You must be root to manage queue files.\n";
}


open(QUEUE, "$LISTQ |") || 
  die "Can't get pipe to $LISTQ: $!\n";

my $entry = <QUEUE>;	# skip single header line
$/ = "";		# Rest of queue entries print on
	    # multiple lines.
while ( $entry = <QUEUE> ) {
#    if ( $entry =~ / $email_addr$/m ) {
    if ( $entry =~ /$email_addr[^\s]*$/m ) {
	($qid) = split(/\s+/, $entry, 2);
	$qid =~ s/[\*\!]//;
	next unless ($qid);

	#
	# Execute postsuper -d | -h | -H with the queue id.
	# postsuper provides feedback when it deletes
	# messages. Let its output go through.
	#
	if ( system($POSTSUPER, $func, $qid) != 0 ) {
	    # If postsuper has a problem, bail.
	    die "Error executing $POSTSUPER: error " .
	       "code " .  ($?/256) . "\n";
	}
    }
}
close(QUEUE);

if (! $qid ) {
    die "No messages with the address <$email_addr> " .
      "found in queue.\n";
}

exit 0;